主页 / 问题 / 1025230
Accepted
user8494502
Asked:2020-09-17 17:48:27 +0800 CST2020-09-17 17:48:27 +0800 CST

(bat) 从 if 访问变量

  • 772

有必要阻止bat文件并遇到问题。带有循环的代码，其中有一个条件。如果满足条件，则分配一个变量。我希望在 echo qwe 然后 ewq 中看到，但最初我只看到循环外的赋值（2 次）。 

 @echo off 
    SetLocal EnableExtensions
    Set a=q
    Set C=1 3 2
    FOR %%x IN (%C%) DO (
    IF %%x==1 ( 
    Set a=qwe
    echo %a%
    )
    IF %%x==2 (
    Set a=ewq
echo %a%
    )
    )
    pause

如果我删除初始分配 Set a=q，然后我得到“回显命令输出模式被禁用”，就是这样。如何分配和访问变量？

bat

1 个回答

  1. Best Answer

    我希望在 echo qwe 然后 ewq 中看到，但最初我只看到循环外的赋值（2 次）。

    必须启用EnableDelayedExpansion和使用!a!。

    当 EnableDelayedExpansion 关闭（未设置）时，变量的值在块启动时是固定的，对它们的任何更改都将被忽略。即使它被前一行以某种方式改变了。

    EnableDelayedExpansion开启时，变量的值同样是固定的，如果使用百分号则访问时获取固定值，如果使用感叹号则改变。

    要解析的代码：

    @echo off 
cls
SetLocal 
set test=test
echo Without EnableDelayedExpansion
for %%x in (1) do (
    set test=altered
    echo %test%
    echo !test!
)
echo finally: %test%
SetLocal EnableDelayedExpansion
set test=test
echo.
echo With EnableDelayedExpansion
for %%x in (3) do (
    set test=altered
    echo %test%
    echo !test!
)
echo finally: %test%

    如果我删除初始分配，Set a=q那么我会得到“回显命令输出模式已禁用”

    必须预见到这样的事件。

    这是正确的代码：

    @echo off 
SetLocal EnableExtensions EnableDelayedExpansion
Set a=q
Set C=1 3 2
FOR %%x IN (%C%) DO (
    IF "%%x"=="1" ( 
        Set a=qwe
        echo !a!
    )
    IF "%%x"=="2" (
        Set a=ewq
        echo !a!
    )
)
pause
    • 2

相关问题