将字节反转为十六进制

几种可能的方法：

procedure TForm2.Button20Click(Sender: TObject);
var
  a, b, c, d, e: DWord;

function ReverseD0(i: DWord): DWord;  //32 bit
asm
  bswap eax
end;

function ReverseD1(i: DWord): DWord;
begin
  Result := ((i and $FF) shl 24) or
            (((i shr 8) and $FF) shl 16) or
            (((i shr 16) and $FF) shl 8) or
            (((i shr 24) and $FF));
end;

function ReverseD2(i: DWord): DWord;
var
  c, d: LongRec;
begin
  c := LongRec(i);
  d := Longrec(Result);
  d.Bytes[0] := c.Bytes[3];
  d.Bytes[1] := c.Bytes[2];
  d.Bytes[2] := c.Bytes[1];
  d.Bytes[3] := c.Bytes[0];
end;

function ReverseD3(i: DWord): DWord;
var
  c: Integer;
begin
  for c := 0 to 3 do
     PByteArray(@Result)[c] := PByteArray(@i)[3-c];
end;

begin
  a := $AABBCCDD;
  b := ReverseD0(a);
  c := ReverseD1(a);
  d := ReverseD2(a);
  e := ReverseD3(a);
  Memo1.Lines.Add(Format('%x %x %x %x %x', [a, b, c, d, e]));
end;

>>>  AABBCCDD DDCCBBAA DDCCBBAA DDCCBBAA DDCCBBAA

“十六进制”是人类表示数字的方式，我假设您只有一个数字，而不是字符串。

program Reverse;

var
  hexValue, x, r: Int64;
//***********************************************************************  
 //Не знаю как с этим компилятором вывести hex 
 //для вывода эта функция
function IntToHex(Value: Int64): string;
var pos:integer;
    HexChars:string;
    Result:string;
begin 
Result:='';
while Value>0 do
  begin
   HexChars := '0123456789ABCDEF';
   pos:=Value mod $10;
   Result := HexChars[pos + 1] + Result;
   Value:=Value div $10;
  end;
  IntToHex:= Result;
end;
//************************************************************************
// программа  реверс
begin
  hexValue := $2300FFC0;// Оставим исходное число для вывода, по желанию
  x:= hexValue;
  r := 0;
  while x > 0 do 
  begin
    r := r * $100 + (x mod $100); // остаток от деления прибавляем к перевертышу 
    x := x div $100; 
  end;
  writeln('hexValue  ',IntToHex(hexValue));
  writeln('Reverse   ',IntToHex(r));


end.

Output:

hexValue  2300FFC0
Reverse   C0FF0023

https://onecompiler.com/pascal/42xjbtcsm

也许 C 程序会帮助你
（uint32_t这是一个 32 位大小的无符号整数类型）

#include <stdio.h>
#include <stdlib.h>
#include <stdint.h>

int
main (int ac, char *av[])
{
  uint32_t v = av[1] ? atoi(av[1]) : 0x2300FFC0;

  printf("source: 0x%08x\n", v);

  uint32_t r = ((v & 0xff) << 24) |
    (((v >> 8) & 0xff) << 16) |
    (((v >> 16) & 0xff) << 8) |
    (((v >> 24) & 0xff));

  printf("result: 0x%08x\n", r);

  return puts("End") == EOF;
}