主页 / 问题 / 1002917
Accepted
AlexKnow
Asked:2020-07-15 17:58:25 +0000 UTC2020-07-15 17:58:25 +0000 UTC

如何在 PHP 中使用字符键获取关联集合？

  • 772

Oracle 数据库具有以下形式的集合：

TYPE error_list_t IS TABLE OF SYS.ODCIVarchar2List INDEX BY varchar2(30)

填写过程如下：

procedure set(name varchar2, value varchar2)
error_list error_list_t;
begin
    if not error_list.exists(name) then
        error_list(name) := SYS.ODCIVarchar2List();
    end if;

    error_list(name).extend;
    error_list(name)(error_list(name).count) := value;

end set;

有必要从 PHP 中获取这个集合，保存name.

此外，该项目使用Doctrine2 ORM。如果有机会使用它，那将是完美的。

php

1 个回答

  1. Best Answer

    oci_bind_array_by_name函数的文档没有提到数组的替换，既不是二维的，也不是与字符键相关的。所以获取这样的数组作为参数或返回值是行不通的。

    最简单的解决方案是将此数组作为常规查询的ResultSet。您将需要添加一个管道函数及其相应的数据类型。这是一个工作示例：

    create or replace package pkg as
    type errorListT is table of SYS.ODCIVarchar2List index by varchar2 (30);
    type errorT is record (name varchar2(30), value varchar(32767)); 
    type errorsT is table of errorT;
    function getErrorList return errorsT pipelined;
end;    
/
create or replace package body pkg as
    -- это тестовые данные заменяющие результат процедуры set() в вопросе
    errors errorListT := errorListT (
        'name1'=>sys.ODCIVarchar2List ('error text 11','error text 12'),
        'name2'=>sys.ODCIVarchar2List ('error text 21','error text 22')); 
    function getErrorList return errorsT pipelined is
        name varchar2 (30) := errors.first; 
    begin
        while name is not null loop
            for ix in 1..errors(name).count loop
                pipe row (errorT (name, errors(name)(ix)));
            end loop;
            name := errors.next(name);
        end loop; 
        return;
    end;
end;
/

    调用和结果将如下所示：

    select * from table (pkg.getErrorList ()) order by name
/
NAME     VALUE           
-------- ----------------
name1    error text 11   
name1    error text 12   
name2    error text 21   
name2    error text 22
    • 3

相关问题