主页 / 问题 / 1032060
Accepted
Viktorov
Asked:2020-10-07 20:22:28 +0000 UTC2020-10-07 20:22:28 +0000 UTC

如何获取块中所有被调用过程的子sql_Id的层次结构？

  • 772

我有一段代码，其中调用了其他程序。示意图如下所示：

begin
  procedure_0;
  procedure_1;
  procedure_2;
  ....
end;

在被调用的过程中，执行各种 DDL 和 DML。所有这些建设工作的时间长得令人无法接受。我有sql_id这个来自 EM 的块。我想以某种方式sql_id为这个块建立一个所有孩子的层次结构，看看在哪里花费了多少时间。

请告诉我如何解决这个问题？

sql

1 个回答

  1. Best Answer

    使用 11.1 版中提供的 PL/SQL 分析器可以轻松解决该任务。

    该功能是默认安装的。您只需要授予EXECUTE包权限DBMS_HPROF并在模式中创建几个表：

    --AS SYS
SQL> grant execute on sys.dbms_hprof to you;
-- в целевой схеме
exec dbms_hprof.create_tables;

    试用包：

    create or  replace package pack0 as
    procedure starter;  
end;
/
create or replace package body pack0 as
    procedure starter is  
        res number;
        procedure proc1 is begin select 111 into res from dual; end;
        procedure proc2 is begin select 222 into res from dual; end;
        procedure proc3 is begin select 333 into res from dual; end;
    begin
        proc1;
        proc2;
        proc3;
    end starter;
end pack0;    
/

    这是运行和分析分析器数据的方法：

    set autoprint on
var runid  number;
exec -
    dbms_hprof.start_profiling ('TEMPFILES', 'pack0.trc'); -
    pack0.starter; -
    dbms_hprof.stop_profiling; -
    :runid := dbms_hprof.analyze ('TEMPFILES', 'pack0.trc', run_comment =>'prof pack0');

RUNID
-
1

    查询和结果：搜索sql_id和执行时间（以微秒为单位）： 

    select 
    rpad (' ', (level-1)*2, ' ')||ltrim (fi.module||'.'||function, '.') name, 
    namespace ctx, sql_id, substr (sql_text, 1, 16) sqltxt, 
    fi.function_elapsed_time elapsed, fi.subtree_elapsed_time total 
from dbmshp_function_info fi
left join dbmshp_parent_child_info pci on (
    pci.runid = fi.runid and pci.childsymid = fi.symbolid)
where  fi.runid = :runid
connect by prior symbolid = parentsymid
and coalesce (owner, user) = user
start with parentsymid is null
/
NAME                               CTX   SQL_ID        SQLTXT              ELAPSED      TOTAL
---------------------------------- ----- ------------- ---------------- ---------- ----------
PACK0.STARTER                      PLSQL                                         5        323
  PACK0.STARTER.PROC1              PLSQL                                        44        136
    PACK0.__static_sql_exec_line4  SQL   gatp22snjsz4k SELECT 111 FROM          92         92
  PACK0.STARTER.PROC2              PLSQL                                        25         96
    PACK0.__static_sql_exec_line5  SQL   7z2m0xcm9hxmf SELECT 222 FROM          71         71
  PACK0.STARTER.PROC3              PLSQL                                        23         86
    PACK0.__static_sql_exec_line6  SQL   12rx46da4214c SELECT 333 FROM          63         63
DBMS_HPROF.STOP_PROFILING          PLSQL                                         0          0

    有关详细信息，请参阅使用 PL/SQL Hierarchical Profiler 。

    • 3

相关问题