Haskell：是否可以将长度为 n 的列表的元素应用于函数？

“橡胶”curry当然可以。您的示例 cfoldl不起作用，因为每次迭代的结果必须是相同的类型，但您的类型不同：第一次迭代Bool -> Bool -> Bool，第二次Bool -> Bool，第三次Bool。

但是 Haskell 有一种机制，允许您创建具有可变参数类型的函数。这种机制就是类。

class CallWithBoolList f where
    t :: f -> [Bool] -> Bool

这里f, 是您要使用列表中的参数调用的函数类型，并且t是您的搜索函数。它的第一个参数是一个函数f，它的第二个参数是一个参数列表，它返回f使用这些参数调用的结果。

第一种情况是基本的：一个空的参数列表。在这种情况下，函数类型f简单地退化为Bool. 毕竟，没有参数的函数只是一个值。让我们写：

instance CallWithBoolList Bool where
    t b [] = b
    t _ _ = error "Слишком много аргументов"

请注意，如果您在此处传递非空列表，则会引发错误。我会回到这个。

第二种情况是递归的：一个由头和尾组成的参数列表。在这种情况下，函数的类型f必须是Bool -> a，其中Bool是它的第一个参数，并且a是函数的“余数”，也就是说，一个函数需要除第一个参数之外的所有参数，然后返回一个值。让我们写：

instance CallWithBoolList a => CallWithBoolList (Bool -> a) where
    t f (x:xs) = t (f x) xs
    t _ [] = error "недостаточно аргументов"

在这里，函数t将第一个参数（列表的“头”）传递给函数f，该函数返回“函数的剩余部分”，然后将其t与其余部分一起传递给函数的“先前”版本参数（列表的“尾部”）。

让我们检查一下它是如何工作的：

f1 x = not x
f2 x y = x && y
f3 x y z = x && y && z
f4 x y z w = x && y || z && w

main = do
    print $ t f1 [True] -- выводит False
    print $ t f2 [True, False] -- выводит False
    print $ t f3 [True, False, True] -- выводит False
    print $ t f4 [True, True, False, False] -- выводит True
    print $ t f1 [True, False] -- ошибка: слишком много аргументов

这种方法可以推广到任何类型，而不仅仅是Bool. 该类及其实现将如下所示：

class CallWithList f res where
    t' :: f -> [res] -> res

instance CallWithList res res where
    t' res [] = res
    t' _ _ = error "слишком много аргументов"

instance CallWithList f res => CallWithList (res -> f) res where
    t' f (x:xs) = t' (f x) xs
    t' _ [] = error "недостаточно аргументов"

唯一的区别是额外的变量res，它存在于类和实现中，替换了类型Bool。

但是，看看你的评论，我怀疑这正是你想要的。特别要注意，在我的实现中，如果t使用“错误”数量的参数调用函数，则会引发错误。但是对于我在评论中关于在这种情况下应该发生什么的问题，您回答：

fn这些“不是三个”元素必须作为论据进来。假设“不是三”是二。然后fn会有Bool -> Bool -> Bool

这是不可理解的。例如，以下程序应该如何工作：

main = do
    let f x y z = x && y && z
    print $ t f [True, False]

在我的实现中，它会在运行时抛出一个错误。你在期待什么？

假设你说这样的程序不应该编译。好的，然后让用户输入参数列表：

main = do
    let f x y z = x && y && z
    args <- read <$> readLine
    print $ t f args

然后怎样呢？不清楚。

如果您指定您希望看到的确切内容，也许我可以提供更好的解决方案。