哪些任务使用显式或隐式游标？

TS 在问题和评论中提到的完整引用：

因此，而不是措辞“显式或隐式？” 一个更好的问题是“封装的还是开放的？” 答案是：始终通过将单行查询隐藏在函数接口（最好是批处理接口）后面并通过 RETURN 返回数据来封装单行查询。

我敢简单解释一下：应该少注意显式和隐式游标之间的选择，最好注意在批处理函数中包含重复请求，从而对用户隐藏它们。

巩固书中介绍的材料的实际示例：

Feuerstein S., Pribyl B. “Oracle PL/SQL。面向专业人士”第 6 版。- 圣彼得堡：彼得，2015 年。
第 15 章，子章节“显式和隐式游标之间的选择”

这些示例将帮助您了解如何使用两种类型的游标：显式游标和隐式游标，在显式游标具有结果数据集的强类型和弱类型的情况下。

测试数据和包装规格：

create table params as 
    select 'key'||level key, 'value'||level value , 'memo about this param' memo
    from dual connect by level<=3;
/
create or replace package democursor as
    type paramtype is record (key varchar2 (8), value varchar2 (16));
    type weakcurtype is ref cursor;
    type strongcurtype is ref cursor return paramtype;
    type paramstype is table of paramtype;
    
    function getParam (key varchar2) return paramtype;  
    procedure openParams (cur out strongcurtype);  
    function getParams (likevalue varchar2) return paramstype;  
end;
/
create or replace package body democursor as
    function getParam (key varchar2) return paramtype is
        param paramtype;
    begin 
        select key, value into param
        from params
        where key = getParam.key;
        return param;
    exception when no_data_found then null;     
    end getParam;
    procedure openParams (cur out strongcurtype) is  
    begin
        open cur for 
            select key, value 
            from params order by key;
    end openParams;
    function getParams (likevalue varchar2) return paramstype is
        cur weakcurtype;
        params paramstype; 
    begin
        open cur for select key, value from params 
        where value like likevalue||'%' order by key;
        fetch cur bulk collect into params;
        close cur; 
        return params;
    end;
end;
/

使用包中的游标和函数的各种情况的示例：

var rc refcursor;  
declare 
    param1 democursor.paramtype;
    param2 democursor.paramtype;
    params democursor.paramstype;

    function getParam (nth int) return democursor.paramtype is
        cur democursor.strongcurtype;   
        ret democursor.paramtype; 
    begin 
        democursor.openParams (cur);
        <<fechnth>> loop 
            fetch cur into ret; 
            exit fechnth when cur%rowcount = nth or cur%notfound;  
        end loop; 
        return ret;
    end; 
begin 
    param1 := democursor.getParam (key=>'key1');
    param2 := getParam (nth=>2); 
    params := democursor.getParams (likevalue=>'val');
    
    open :rc for 
        select 'got first param' what, param1.key||'='||param1.value param from dual union all
        select 'got nth=2 param' what, param2.key||'='||param2.value param from dual union all
        select 'got val% params' what, params.key||'='||params.value from table (params) params;
end;
/ 

工作成果：

WHAT            PARAM                                                            
--------------- -----------------------------------------------------------------
got first param key1=value1                                                      
got nth=2 param key2=value2                                                      
got val% params key1=value1                                                      
got val% params key2=value2                                                      
got val% params key3=value3   

上面的可重现示例已放在db<>fiddle上进行修改，以便尝试更好地理解使用游标的某些方面。