主页 / 问题 / 1212008
Accepted
LEON
Asked:2021-12-01 00:58:28 +0000 UTC2021-12-01 00:58:28 +0000 UTC

通过汇编程序调用 GetSystemInfo 函数

  • 772

我在 winapi (sysinfoapi.h) 中内置了一个 GetSystemInfo 函数，我该如何调用它？

然后将函数调用的响应放入内存位置。

C++：

void GetSystemInfo(
  LPSYSTEM_INFO lpSystemInfo
);

官方文档：https ://docs.microsoft.com/en-us/windows/win32/api/sysinfoapi/nf-sysinfoapi-getsysteminfo

这就是我能找到的。

winapi

1 个回答

  1. Best Answer

    免责声明：

    用汇编程序编写这段代码是没有意义的，用 C 编写同样的东西会容易得多（在示例的末尾）。

    尽可能少的 fasm 示例，结果是一个 32 位控制台 exe 文件：

    format PE CONSOLE
entry start

include 'win32a.inc'

section '.text' code readable executable

  start:
    invoke GetSystemInfo, system_info

    ; dword перед [system_info.wProcessorArchitecture] нужно из-за того что это 2-байтовое поле (word),
    ; его нельзя просто так передать с помощью push.
    ; dword здесь приводит к тому, что по адресу поля читается 4 байта вместо 2.
    ; Но это корректно работает только потому, что после этого поля идет зарезервированное пустое 2-байтовое поле
    ; (если бы было не пустое, вывелось бы неправильное значение)
    cinvoke printf, format_string, dword [system_info.wProcessorArchitecture], [system_info.dwPageSize]
    invoke getch ; ожидание нажатия клавиши перед завершением, можно и без этого, если запускаете из командной строки
    invoke ExitProcess,0

section '.data' data readable writeable

system_info SYSTEM_INFO

format_string:
    db 'wProcessorArchitecture: %d', 0x0d, 0x0a
    db 'dwPageSize: %d', 0x0d, 0x0a, 0

section '.idata' import data readable writeable

library kernel32, 'KERNEL32.DLL',\
    msvcrt, 'MSVCRT.DLL'

include 'api/kernel32.inc'

import msvcrt,\
    printf,'printf',\
    getch,'_getch'

section '.reloc' fixups data readable discardable

    这里例如只输出前两个字段的值——wProcessorArchitecture和dwPageSize。

    在 32 位版本中，它输出：

    wProcessorArchitecture: 0
dwPageSize: 4096

    0对应PROCESSOR_ARCHITECTURE_INTEL，见结构说明SYSTEM_INFO

    如果您将 PE 代码更改为 PE64 和include 'win32a.inc'，include 'win64a.inc'您将获得一个 64 位可执行文件，输出将如下所示：

    wProcessorArchitecture: 9
dwPageSize: 4096

    9 对应PROCESSOR_ARCHITECTURE_AMD64。

    “魔术”字符串system_info SYSTEM_INFO是一个宏，在编译时，它会扩展为一组相应结构的字段，例如，对于 32 位可执行文件（取自文件fasm/include/equates/kernel32.inc）：

    struct SYSTEM_INFO
  wProcessorArchitecture      dw ?
  wReserved           dw ?
  dwPageSize              dd ?
  lpMinimumApplicationAddress dd ?
  lpMaximumApplicationAddress dd ?
  dwActiveProcessorMask       dd ?
  dwNumberOfProcessors        dd ?
  dwProcessorType         dd ?
  dwAllocationGranularity     dd ?
  wProcessorLevel         dw ?
  wProcessorRevision          dw ?
ends

    对于 64 位版本，一切都相同，只是指针字段（以 开头的lp）的大小不同 - 64 位 ( dq) 而不是 32 位 ( dd)。

    还应该说invoke，cinvoke宏是在编译时根据程序开头包含的文件转换为不同代码的宏 -win32a.inc或win64a.inc.

    对于 32 位版本invoke，它变成 0 或更多push，call最后是约定stdcall。因为cinvoke顺序是push相反的，然后call堆栈与传递的参数的大小对齐push- 一个协议cdecl（用于具有可变数量参数的函数，就像同一个printf）。请参阅在 x86 上使用 32 位寻址的调用约定。

    对于 64 位版本，一切都有些复杂，可以参考这里：Calling convention for 64-bit systems

    PS或多或少等效的C代码：

    include <windows.h>
include <stdio.h>

SYSTEM_INFO system_info;

int main() {
    GetSystemInfo(&system_info);
    printf("wProcessorArchitecture: %d\n"
           "dwPageSize: %d\n",
           system_info.wProcessorArchitecture,
           system_info.dwPageSize);
    // Тут мог быть вызов getch();, но эта функция не входит в стандарт, поэтому не добавляю
    return 0;
}
    • 2

相关问题