箭头大小向量 gnuplot

很奇怪，你的风格增加了箭头的长度。该参数size指定箭头的每个分支（翅膀）的长度，而不仅仅是它的长度。在您的情况下，根本没有箭头-它将显示为简单的破折号（我使用了 gnuplot 5.2.8，但我认为这并不重要），因为您没有指定head. 此破折号的长度dx在dy命令中指定为参数plot。除了箭头分支的长度之外，最好设置分支与轴的发散角：这些参数 (size和angle) 的组合最终将给出箭头的长度。backangle好吧，为了更美，设置参数（箭头后线的张角）并在箭头的前后fill线之间进行填充也是有意义的。代替fill. 您也可以使用该参数noborder- 只有“填充”的箭头部分可见，而线条本身将不可见（因此箭头会略小）。最后一个参数也推荐在不是用实线来绘制“破折号”，而是有一些风格，比如虚线。

现在我们可以继续看例子。在脚本中，我定义了几种箭头样式。

reset

set style arrow 1 head size 0.5,3,25 filled lc rgbcolor "blue" lw 2
set style arrow 2 head size screen 0.1,3,25  noborder lc rgbcolor "blue" lw 2
set style arrow 3 head size 0.15, 10,60 fixed filled lc rgbcolor "green"
set style arrow 4 size 3

# следующие два параметра задают общее количество вычисляемых точек для графика
set samples 10
set isosamples 10,10

set xrange [-pi:pi]
set yrange [-pi:pi]

# это даст стрелки различной длины
#dx(x) = sin(x/2.0)
#dy(x) = cos(x)

# это даст стрелки одинаковой длины
dx(x) = 0.2 * sgn(sin(x))
dy(x) = 0.2 * sgn(cos(x))

plot "++" using 1:2:(dx($1)):(dy($2)) w vec arrowstyle 1 title 'Направление какого-то поля'

我的示例中的样式 1指定了一个带填充的箭头（带有参数head），翼长为 0.5（默认情况下，根据文档，使用与轴重合x的坐标系，但可以指定坐标系明确地说，就像我对样式 2 所做的那样）。除了箭翼的长度，我还设置了前后线的偏离角度，形成了箭本身。好吧，我仍然应用填充。您还可以在此处看到用于控制线条样式的标准工具可以应用于箭头（我设置了线条的颜色和粗细）。

样式 2fill的不同之处在于我使用“屏幕坐标”来指定箭头翅膀的长度，而不是填充关键字，我使用noborder，这样箭头的边框线就不会被绘制。同时，虽然我们自己没有画线，但是lw设置线粗细的参数还是会影响外观。

样式 3在大小块 ( ) 之后size ...使用关键字fixed。据我了解，它强制gnuplot绘制所有相同大小的箭头（即带有“翅膀”的部分）（无论 , 的值如何） dx，dy并且与 的值不成比例dx, dy.

dx在示例中，为了清楚起见，我将值 ​​​​\u200b\u200bfixed in value for dy。您可以注释掉这些函数并取消注释它们的可变长度版本，然后您将看到样式 3 与其他样式有何不同。

样式 4是您问题中的样式，因此您也可以看到它。

下面是使用样式 1 的图表。

UPD： 绘制边框的样式可以与箭头本身的填充样式不同吗？也就是说，例如，我想用一种颜色绘制箭头，并用另一种颜色填充引导提示？

我没有找到直接的方法来做到这一点，但你可以做类似的事情。我将只为上面已经存在的示例提供更改（添加）的行。您可以制作两种样式的箭头 - 一种是“带空”箭头，另一种完全相同，但没有线条（通过noborder）。然后就画两张图，一张在一张上面，参数一样，依次使用这些样式：

set style arrow 5 head size 0.7,3,25 empty lc rgbcolor "blue" lw 2 
set style arrow 6 head size 0.7,3,25 noborder lc rgbcolor "red" lw 2 

plot "++" using 1:2:(dx($1)):(dy($2)) w vec arrowstyle 5 title 'Направление какого-то поля',\
"++" using 1:2:(dx($1)):(dy($2)) w vec arrowstyle 6 notitle

这种方法有一个缺点：我不知道是否可以在图例中形成相同的箭头（可能不是）。也就是说，使用这种绘制方法，最好完全删除图例（在示例中，我为“空”箭头留下了图例，并删除了填充的图例）。

结果，结果是这样的：

当然，如果您更改这些图表的绘制顺序，外观可能会略有变化，但lw最好将线粗（参数 ）减少到至少 1。