主页 / 问题 / 1260566
Accepted
Анатолий Эрнст
Asked:2022-03-25 16:11:09 +0000 UTC2022-03-25 16:11:09 +0000 UTC

如何提供全局会话间上下文 - 所有会话的一个变量？

  • 772

您想阻止批处理过程再次运行。但是我不想在表中使用当前启动的标志，我想从内存中获取它。据我从文档中了解到，全局上下文仅在特定会话中可用。

您如何以某种简单优雅的方式提供闭会期间的交流？

也就是说，所有会话的一个变量。

sql

1 个回答

  1. Best Answer

    全局上下文仅在特定会话中可用

    并非如此，通过添加一个子句ACCESSED GLOBALLY，上下文将在所有会话中可用。

    看一看（或尝试一下）：

    create or replace context gctx using gpack accessed globally
/
create or replace package gpack as
    function getnamespace return varchar2;
    procedure setctx (attr varchar2, value varchar2);
    procedure clearctx (attr varchar2); 
end;
/
create or replace package body gpack as
    function getnamespace return varchar2 is begin return 'gctx'; end;
    procedure setctx (attr varchar2, value varchar2) is
    begin
        dbms_session.set_context (namespace=>getnamespace, attribute=>attr, value=>value);
    end;
    procedure clearctx (attr varchar2) is
    begin
        dbms_session.clear_context (namespace=>getnamespace, attribute=>attr);
    end;
end;
/

    在会话 A 中：

    select sys_context ('userenv', 'sessionid') sid from dual
/
SID
------
639285

exec gpack.setctx ('something', 'lock') 

select sys_context (gpack.getnamespace, 'something') something from dual;

SOMETHING
---------
lock

    在会话 B 中：

    select sys_context ('userenv', 'sessionid') sid from dual
/
SID
--------------------------------------------------------------------------------
639321

select sys_context (gpack.getnamespace, 'something') something from dual
/
SOMETHING
--------------------------------------------------------------------------------
lock

    更多细节在ch。全局应用程序上下文文档。

    • 3

相关问题