主页 / 问题 / 1277024
Accepted
ugorek
Asked:2022-05-01 18:08:03 +0000 UTC2022-05-01 18:08:03 +0000 UTC

为没有边框的窗口添加阴影（几乎完成）

  • 772

无边框窗口 ( BorderStype = bsNone) 可能看起来太平且不熟悉。因此，在网上搜索后，我能够理解如何手动添加阴影：

  TForm1 = class(TForm)
   ...
   procedure CreateParams(var Params:TCreateParams); override;
  end;
 
procedure TForm1.CreateParams(var Params:TCreateParams);
 begin
  inherited;
  Params.Style:=Params.Style or WS_SIZEBOX; //WS_THICKFRAME
 end;

结果证明是您所需要的，但有些意外。除了阴影之外，还出现了一条白色细条纹代替窗口标题（Windows 10）。

带阴影的无框窗

我的技能已经不足以自己移除它了。这结束了我的权力：C

  1. 这个白色条纹怎么去掉？
  2. 还是有另一种方法可以将普通阴影（如有边框的窗口）添加到无边框窗口？
  3. 也有一个选项Params.WindowClass.Style := Params.WindowClass.Style or CS_DROPSHADOW;，但它不适合。阴影完全不同，不适合可调整大小的窗口。
delphi

1 个回答

  1. Best Answer

    这解决了我所有的问题：

     
interface
 
 uses
  Windows,Messages,SysUtils,Controls,Forms,DwmApi,UxTheme,Classes,StdCtrls;
 
 type
  TForm1=class(TForm)
   function SetBordelessShadow:Boolean;
   procedure CreateWindowHandle(const AParams:TCreateParams); override;
   procedure WndProc(var AMsg:TMessage); override;
  end;
 
 var
  Form1:TForm1;
 
implementation
 
{$R *.dfm}
 
function TForm1.SetBordelessShadow:Boolean;
  var
   LMargins:TMargins;
   LPolicy:LongInt;
 begin
  LPolicy:=DWMNCRP_ENABLED;
  Result:=Succeeded(DwmSetWindowAttribute(Handle,DWMWA_NCRENDERING_POLICY,@LPolicy,SizeOf(Integer)))and(DwmCompositionEnabled);
  if Result then
   begin
    LMargins.cxLeftWidth:=1;
    LMargins.cxRightWidth:=1;
    LMargins.cyTopHeight:=1;
    LMargins.cyBottomHeight:=1;
    Result:=Succeeded(DwmExtendFrameIntoClientArea(Handle,LMargins));
   end;
 end;
 
procedure TForm1.CreateWindowHandle(const AParams: TCreateParams);
 begin
  inherited;
  if TOSVersion.Major>=6 then
   SetBordelessShadow;
 end;
 
procedure TForm1.WndProc(var AMsg:TMessage);
 begin
  case AMsg.Msg of
   WM_DWMCOMPOSITIONCHANGED,WM_DWMNCRENDERINGCHANGED:
    if SetBordelessShadow then
     Exit;
  end;
  inherited;
 end;
 
end.
    • 0

相关问题