主页 / 问题 / 1401647
Accepted
kioley
Asked:2022-06-19 12:15:54 +0000 UTC2022-06-19 12:15:54 +0000 UTC

关于函数式编程中的状态

  • 772

FP中的状态是个很奇怪的东西，好像有，但又好像没有。

请用一个简单的例子来解释。我们制作了一个简单的按钮计算器。在过程编程中，按数字键会更改变量x，然后是算术运算符的变量，然后是变量y。在按下等号按钮之前，我们可以随时添加一元减号、百分号来更改操作。所有这些都存储在一个状态中（在这种情况下，在变量中）。单击等号按钮会调用一个可以使用纯函数的有状态过程，但它必须将状态传递给它们。计算出的答案作为新的x转移到状态（已分配）可以继续计算。在 OOP 中也发生了大致相同的事情，只不过不是使用过程，而是使用与其状态一起工作的对象方法。程序可能不同，但本质是这样的——一个过程或方法处理某种状态。

问题：如何在 FP 中编写这样一个与之前的用户输入一起逐步工作的计算器？它会存储程序的一些中间状态吗？理想情况下，一些命令式语言的函数式示例会很好，但如果可能的话，不要使用变量。例如在 js 或 python 中。但是函数式语言中的例子有解释也很讨喜。

scala

0 个回答

  1. Best Answer

    函数式语言中的状态作为附加参数传递给函数。新状态与结果一起由函数返回。

    这是来自 Haskell 的示例，其中随机数生成器的种子用作状态，小数和符号的对用作结果

    import System.Random

randomPair :: StdGen -> ((Double, Char), StdGen)
randomPair gen = ((num, chr), gen'')
  where
    (num, gen')  = randomR (5, 10) gen
    (chr, gen'') = randomR ('a', 'z') gen'

    ghci> randomPair $ mkStdGen 0
((7.100453103162899,'p'),StdGen {unStdGen = SMGen 14141672759607663454 16294208416658607535})
ghci> randomPair $ mkStdGen 1
((5.607634207178038,'c'),StdGen {unStdGen = SMGen 15450470250919199918 10451216379200822465})

    诚然，当手动传输状态时，很容易混淆，所以传输隐藏在 monads 和语法糖之后。

    import System.Random
import Control.Monad.State

randomR' :: Random a => (a, a) -> State StdGen a
randomR' = state . randomR

randomPair' :: State StdGen (Double, Char)
randomPair' = do
  num <- randomR' (5, 10)
  chr <- randomR' ('a', 'z')
  return (num, chr)

    甚至如此

    randomPair' :: State StdGen (Double, Char)
randomPair' = liftM2 (,) (randomR' (5, 10)) (randomR' ('a', 'z'))

    ghci> runState randomPair' $ mkStdGen 0
((7.100453103162899,'p'),StdGen {unStdGen = SMGen 14141672759607663454 16294208416658607535})
ghci> runState randomPair' $ mkStdGen 1
((5.607634207178038,'c'),StdGen {unStdGen = SMGen 15450470250919199918 10451216379200822465})

    在图形应用程序中，处理事件的函数可以负责更新状态。

    {-# LANGUAGE OverloadedStrings #-}

import CodeWorld

main :: IO ()
main = activityOf emptyState processEvent draw

emptyState :: [Point]
emptyState = []

processEvent :: Event -> [Point] -> [Point]
processEvent (PointerPress point) state = point : state
processEvent (KeyPress "C")       state = emptyState
processEvent _                    state = state
    
draw :: [Point] -> Picture
draw state =
  pictures
    [ lettering "Click to add point, press 'C' to clear"
    , colored red $ foldMap drawPoint state
    , colored blue $ polyline state
    ]
    
drawPoint :: Point -> Picture
drawPoint (x, y) = translated x y $ solidCircle 0.2

    https://code.world/haskell#P46Xg_hOf3WCB_Ycx1rfF4w

    • 2

相关问题