主页 / 问题 / 1447247
Accepted
Kromster
Asked:2022-09-10 03:07:16 +0000 UTC2022-09-10 03:07:16 +0000 UTC

如何在 Delphi 中的 `OnMouseMove` 处理程序中确定事件源是相对的还是绝对的（鼠标或平板电脑）？

  • 772

我的电脑有 2 个交替使用的输入设备 - 鼠标和图形输入板 (Wacom)。如您所知，鼠标生成相对坐标（类型为X +5 Y +1），而数位板生成绝对坐标（类型为X 567 Y 876）。Windows 获取它们并将它们转换为绝对值，然后再将它们发送到应用程序。

如何在事件处理程序中确定事件OnMouseMove来自哪个设备，以及新坐标是由相对输入设备还是绝对输入设备生成的？理想情况下 - 从输入设备查看“原始”事件。

我看到添加的标志ssTouch ssPen中有标志（内部调用MSDN），但似乎它们指的是平板电脑，而不是单个平板电脑作为输入设备。TShiftStateMouseOriginToShiftStateGetMessageExtraInfo

我也听说有RAWMOUSE structure (winuser.h)/ MOUSE_MOVE_RELATIVE（MOUSE_MOVE_ABSOLUTEMSDN ），但是怎么用还不清楚。

windows

0 个回答

  1. Best Answer

    1. 为“原始”事件注册一个监听器（否则它们不会出现）并订阅接收事件：

      procedure RegisterListener;
const
  // https://docs.microsoft.com/en-us/windows-hardware/drivers/hid/hid-usages#usage-page
  HID_USAGE_PAGE_GENERIC = 1;
  HID_USAGE_PAGE_GAME = 5;
  HID_USAGE_PAGE_LED = 8;
  HID_USAGE_PAGE_BUTTON = 9;
  // https://docs.microsoft.com/en-us/windows-hardware/drivers/hid/hid-usages#usage-id
  HID_USAGE_GENERIC_MOUSE = 2;
  HID_USAGE_GENERIC_KEYBOARD = 6;
var
  rid: tagRAWINPUTDEVICE;
begin
  // To receive WM_INPUT messages, an application must first register the raw input devices using RegisterRawInputDevices.
  // By default, an application does not receive raw input.
  rid.usUsagePage := HID_USAGE_PAGE_GENERIC;
  rid.usUsage := HID_USAGE_GENERIC_MOUSE;
  rid.dwFlags := 0;
  rid.hwndTarget := 0; // If NULL it follows the keyboard focus
  RegisterRawInputDevices(@rid, 1, SizeOf(rid));
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  RegisterListener;
  Application.OnMessage := OnMessage;
end;

    2. 现在，在事件处理程序中，您可以获得“原始”数据，从中可以找到输入的详细信息。最好不要在这里输入输入本身，因为。它不是高贵的（例如，对于平板电脑，x / y 坐标不会投影到显示器上，而是从 0 到 65535，此外，如果我正确理解文档，则不会应用光标加速等）。

      procedure TForm1.OnMessage(var aMsg: TMsg; var aHandled: Boolean);
var
  dwSize: Cardinal;
  ri: tagRAWINPUT;
begin
  if aMsg.message = WM_INPUT then
  begin
    GetRawInputData(HRAWINPUT(aMsg.lParam), RID_INPUT, nil, dwSize, SizeOf(RAWINPUTHEADER));

    if dwSize = 0 then
      ShowMessage('Can not allocate memory');

    if GetRawInputData(HRAWINPUT(aMsg.lParam), RID_INPUT, @ri, dwSize, SizeOf(RAWINPUTHEADER)) <> dwSize then
      ShowMessage('GetRawInputData doesn''t return correct size!');

    // https://docs.microsoft.com/en-us/windows/win32/api/winuser/ns-winuser-rawinputdevicelist
    // https://docs.microsoft.com/en-us/windows/win32/api/winuser/ns-winuser-rawmouse
    if ri.header.dwType = RIM_TYPEMOUSE then
    begin
      if ri.mouse.usFlags and $1 = 0 then
        fLastInputMode := imRelative
      else
        fLastInputMode := imAbsolute;
    end;
  end;
end;

    3. 现在，有了 flag ，您可以根据类型fLastInputMode更改处理程序中的逻辑：Panel1MouseMove

      procedure TForm1.Panel1MouseMove(Sender: TObject; Shift: TShiftState; X,Y: Integer);
var
  origin: TPoint;
begin
  case fLastInputMode of
    imRelative: begin
                  // Stick mouse cursor to start location, otherwise it stucks at screen border
                  origin := TControl(Sender).ClientToScreen(Point(fOriginCursorX, fOriginCursorY));
                  SetCursorPos(origin.X, origin.Y)
                end;
    imAbsolute: begin
                  // Update tablet cursor origin, otherwise its offset will grow exponentially
                  fOriginCursorX := X;
                  fOriginCursorY := Y;
                end;
  end;

    WinApi的方法和数据结构的描述在github上很容易找到，这里就不一一列举了。如果您对测试项目感兴趣 - https://github.com/Kromster80/raw_input_test/

    • 2

相关问题