主页 / 问题 / 627029
Accepted
Ev_Hyper
Asked:2020-02-13 05:20:29 +0000 UTC2020-02-13 05:20:29 +0000 UTC

获取有关模块中函数的信息

  • 772

对如何获取有关模块包含的功能的信息的问题感兴趣。我想得到类似 FSI 问题的东西。

例如对于以下模块

module Test = 
    let ign _ = ()
    let getNowDateTime() = System.DateTime.Now
    let getNumbers count = [1..count]

FSI 显示此类信息

module Test = begin
  val ign : 'a -> unit
  val getNowDateTime : unit -> System.DateTime
  val getNumbers : count:int -> int list
end

我尝试通过反射获取数据如下

let getInfoAboutModule (t : Type) = 

    let genericToString (t : Type) = 
        match t.GenericTypeArguments with
        | [| |] -> t.FullName
        | x -> 
            x 
            |> Seq.map (fun x -> x.Name)
            |> String.concat "," 
            |> sprintf "%s<%s>" t.Name

    let getInfo (mi:MethodInfo) =
        let parameter = 
            let sb = System.Text.StringBuilder()

            for x in mi.GetParameters() do
                x.ParameterType
                |> genericToString
                |> sprintf "%s : %s ->" x.Name
                |> sb.Append
                |> ignore

            sb.ToString()
            |> fun str -> if str |> System.String.IsNullOrEmpty then "unit -> " else str

        sprintf "%s : %s %s" mi.Name parameter (genericToString mi.ReturnType) 

    t.GetMethods(BindingFlags.Public ||| BindingFlags.Static)
    |> Seq.map getInfo

对于模块，Test结果如下

ign : _arg1 :  -> System.Void
getNowDateTime : unit ->  System.DateTime
getNumbers : count : System.Int32 -> FSharpList`1<Int32>

MCVE (ideone)

但是，当然，通过这种方式我得到的名字与 F# 相去甚远。

PS 您不能向模块添加任何属性，因为 您需要保留从其他程序集的模块中提取数据的能力。

.net

1 个回答

  1. Best Answer

    您可以使用FSharp.Compiler.Service来解析模块源。如果模块已编译且其源代码不可用，那么我怀疑您能否获得比您的更好的结果。

    基于这个例子：

    open System
open System.IO
open Microsoft.FSharp.Compiler.SourceCodeServices

let text =
    """
module Test = 
    let ign _ = ()
    let getNowDateTime() = System.DateTime.Now
    let getNumbers count = [1..count]
    """

let checker = FSharpChecker.Create()

// из примера
let parseAndTypeCheckSingleFile input = 
    let file = "test.fsx"

    let projOptions = 
        checker.GetProjectOptionsFromScript(file, input)
        |> Async.RunSynchronously

    let parseFileResults, checkFileResults = 
        checker.ParseAndCheckFileInProject(file, 0, input, projOptions) 
        |> Async.RunSynchronously

    // Wait until type checking succeeds (or 100 attempts)
    match checkFileResults with
    | FSharpCheckFileAnswer.Succeeded(res) -> parseFileResults, res
    | res -> failwithf "Parsing did not finish... (%A)" res

// печать информации о члене модуля
let printInfo (fn:FSharpMemberOrFunctionOrValue) =
    // строка с информацией о типе
    let rec getTypeString (t:FSharpType) =
        if t.HasTypeDefinition then
            let prms = [ for x in t.GenericArguments -> (getTypeString x) ] in
                t.TypeDefinition.DisplayName +
                " " +
                String.Join(" ", prms)
        else
            t.ToString()

    printf "%s: " fn.DisplayName

    for group in fn.CurriedParameterGroups do
        for prm in group do
            match prm.Name with
                | None -> () 
                | Some name -> printf "%s:" name
            printf "%s -> " (getTypeString prm.Type)

    printf "%s\n" (getTypeString fn.ReturnParameter.Type)


[<EntryPoint>]
let main argv = 
    let parseFileResults, checkFileResults = 
        parseAndTypeCheckSingleFile text 

    let m = checkFileResults.PartialAssemblySignature.Entities.[0]
    let fns = m.NestedEntities.[0].MembersFunctionsAndValues

    for x in fns do printInfo x

    0

    结果：

    ign: type 'a -> unit
getNowDateTime: unit  -> DateTime
getNumbers: count:int  -> list int

    或者您可以直接研究来源FSI。

    如果在解析过程中出现错误，需要将文件复制FSharp.Core.optdata到FSharp.Core.sigdata程序所在的目录下。这些文件可以在%PROFRAMFILES%\Reference Assemblies\Microsoft\FSharp\.NETFramework\v4.0\4.4.0.0\.

    • 4

相关问题