主页 / 问题 / 718015
Accepted
Dr.robot
Asked:2020-09-14 00:17:50 +0000 UTC2020-09-14 00:17:50 +0000 UTC

按顺序重命名文件夹中的文件

  • 772

有必要借助 BAT 文件进行制作，以便在文件夹中启动时，按顺序重命名具有特定扩展名（例如 .jpg）的所有文件，从 1 到文件中的数量文件夹。'比如有这样的文件：daisdasgbdaso.jpg hudsghaiudgag.jpg dhsadhkajshdk.jpg 而你需要输出 1.jpg 2.jpg 3.jpg'

windows

2 个回答

  1. Best Answer

    可以这样做：

    @echo off
setlocal EnableDelayedExpansion

set num=100
for /F "delims=" %%i in ('dir /B *.jpg') do (
   set /A num+=1
   ren "%%i" "!num:~1!.jpg"
)
    • 3

  2. 这是我对类似问题的解决方案。
    地点：

    .bat 文件位于文件夹旁边（结果是文件夹的名称）。
    该文件夹包含需要重命名的文件。
    就我而言，这些是具有不同名称的 .jpg 文件...
    此 .bat 文件会将它们重命名为这些文件 file-000.jpg、file-001.jpg、file-002.jpg

    setlocal enabledelayedexpansion
cd /d Result
set "count=1000"
set a="*.jpg"
for /f "usebackq delims=*" %%f in (`dir /b /o:-d /tc %a%`) do (ren "%%f" file-!count:~1!.jpg
set /a count+=1
)
pause

    SetLocal EnableDelayedExpansion通过符号扩展变量 (!)
    cd /d Result转到 Result 文件夹
    set "count=1000"变量，我在其中表示零的数量file-001.jpg
    set a="*.jpg"变量表示哪些文件我们正在寻找。

    ( dir /b /o:-d /tc %a%)
    dir - 显示文件和子目录的列表。接下来我们排序。
    /b - 仅显示文件名。
    /o:-d - 以相反的顺序（从最新到最旧）对显示的文件列表进行排序。
    /tc - 按文件创建时间排序。
    %a% - 调用变量。

    usebackq指定对文件名使用引号的能力，例如这里> “。
    指定执行包含在反引号中的字符串作为命令，例如这里> `，
    并将单引号中的字符串作为字符串中的命令，例如这里> '。

    delims=xxx指定分隔符集。替换默认分隔符集的空格和制表符。

    • 1

相关问题