主页 / 问题 / 851739
Accepted
Eugene X
Asked:2020-07-08 20:53:43 +0000 UTC2020-07-08 20:53:43 +0000 UTC

Delphi调用对象的地址过程

  • 772

有一个对象的回调

type TTriggerCallback = procedure(Sender: TObject; Props: TBasicTriggerProps) of object;

我将回调的地址添加到列表中

(TriggerList.Objects[Index] as TList).Add(@Callback);

Callback 是一个表单过程

procedure TForm1.FormCreate(Sender: TObject);
begin
    TriggerFac := TTriggerFactory.Create;
    TriggerFac.AttachTrigger('OnNoGuiBootChanged', Self.OnNoGuiBootChanged);
end;

但是当我尝试调用这样的存储函数时，我得到了访问冲突。

var cbkptr: ^TTriggerCallback;

list := TriggerList.Objects[index] as TList;
for I := list.Count-1 downto 0 do begin
    cbkptr := list.Items[i];
    try
        cbkptr^(Sender, Props);
    finally
    end;
end;

同时，@Callback输入和cbkptr输出地址相同，据我了解，似乎Self对象根本没有传输。因为如果你删除 object 并将 Self 作为第一个参数传递，那么一切正常，但在这种情况下它不会。

有没有人有关于如何解决这个问题的建议？

ps：我使用的是Delphi 7，所以TList<TTriggerCallback>我没有它，必须使用直接地址。

delphi

1 个回答

  1. Best Answer

    procedure of object作为记录实施

    TMethod = record
  Code: Pointer;
  Data: Pointer;
end;

    whereCode是指向方法本身的指针，并且Data是您要为其调用方法的对象

    如果您需要将此回调保存到列表中，则需要此代码

    procedure AddToList(const ACallback: TTriggerCallback);
var
  LMethod: PMethod;
begin
  GetMem(LMethod, SizeOf(LMethod^));
  LMethod^ := TMethod(ACallback);
  List.Add(LMethod);
end;

    称呼

    procedure Invoke(AIndex: Integer; Sender: TObject; Props: TBasicTriggerProps);
var
  LMethod: PMethod;
  LCallback: TTriggerCallback
begin
  LMethod := TMethod(List[AIndex]);
  LCallback := LMethod^;
  LCallback(Sender, Props);
end;

    好吧，不要忘记调用FreeMem列表的每个元素

    第二种方式是写一个包装对象

    TTriggerCallbackWraper = class
private
  FCallback: TTriggerCallback;
public
  constructor Create(const ACallback: TTriggerCallback);
public
  property Callback: TTriggerCallback read FCallback;
end;

constructor TTriggerCallbackWraper.Create(const ACallback: TTriggerCallback);
begin
  inherited Create;
  FCallback := ACallback;
end;

    并添加

    procedure AddToList(const ACallback: TTriggerCallback);
begin
  List.Add(TTriggerCallbackWraper.Create(ACallback));
end;

    称呼

    (List[Idx] as TTriggerCallbackWraper).Callback(.......)

    TTriggerCallbackWraper 类的实例必须通过调用Free. 或者改为TList使用TObjectListwith OwnObjects := True;

    • 4

相关问题