绘制不完整的圆GLSL OpenGL [关闭]

例如像这样：

void mainImage( out vec4 fragColor, in vec2 fragCoord )
{
    // Define how blurry the circle should be. 
    // A value of 1.0 means 'sharp', larger values
    // will increase the bluriness.
    float bluriness = 1.0;
    
    // In the range (0, 1].
    float radius = 0.75;
    
    // In the range (0, 1].
    float len = 0.5 + 0.45 * cos( iTime );
    
    // Optional offset.
    float offset = 0.0;
    
    // Calculate texture coordinates. Normally you would
    // simply pass them from the vertex shader.
    vec2 uv = fragCoord.xy / iResolution.xy;
    
    // Convert from range [0,1] to [-1,1]
    uv = 2.0 * uv - 1.0;
    
    // Adjust for the aspect ratio. Not necessary if
    // you supplied texture coordinates yourself.
    uv.x *= (iResolution.x / iResolution.y);
    
    // Calculate distance to (0,0).
    float d = length( uv );
    
    // Calculate angle, so we can draw segments, too.
    float angle = atan( uv.x, uv. y ) / 3.141592 * 0.5;
    angle = fract( angle - offset );
    
    // Create an anti-aliased circle.
    float wd = bluriness * fwidth( d );
    float circle = smoothstep( radius + wd, radius - wd, d );
    
    // Or only draw a portion (segment) of the circle.
    float wa = bluriness * fwidth( angle );
    float segment = smoothstep( len + wa, len - wa, angle );
    segment *= smoothstep( 0.0, 2.0 * wa, angle );    
    circle *= mix( segment, 1.0, step( 1.0, len ) );
        
    // Output final color.
    fragColor = vec4( circle, circle, circle, 1);    
}

// 基于https://www.shadertoy.com/view/Mll3D4