从字符串中选择一个或多个唯一的数字序列

l_sp我不太明白代码中的标志 (和)应该是什么意思l_ep，因此不太明白如何修复它。

您可以基于正则表达式构建查询。

例如，这是一个这样的查询，它从字符串中提取数字序列：

select regexp_substr(p_dbs, '[[:digit:]]+', 1, level) 
  from dual
connect by regexp_substr(p_dbs, '[[:digit:]]+', 1, level) is not null

工作原理：该函数REGEXP_SUBSTR返回字符串中与正则表达式匹配的第 N 个序列。正则表达式[[:digit:]]+提取数字序列。递归查询 ( connect by) 将依次提取所有数字序列，直到它们用完（将返回一个空字符串，即null）。

现在您可以从字符串中提取所需长度的唯一序列：

select t.numbers
  from (select regexp_substr(p_dbs, '[[:digit:]]+', 1, level) as numbers,
               level as l --Номер последовательности с начала строки
          from dual
        connect by regexp_substr(p_dbs, '[[:digit:]]+', 1, level) is not null) t
 where length(t.numbers) in (5, 6) --фильтр по длине
 group by t.numbers
 order by min(t.l) --Сортируем последовательности в оригинальном порядке (если это нужно) 
                   -- Если сортировка не нужна, то можно обойтись DISTINCT
                   -- (убрать GROUP BY и поле L из вложенного запроса)

你可以把它们拿出来：

  for r in (select t.numbers
              from (select regexp_substr(p_dbs, '[[:digit:]]+', 1, level) as numbers,
                           level as l
                      from dual
                    connect by regexp_substr(p_dbs, '[[:digit:]]+', 1, level) is not null) t
             where length(t.numbers) in (5, 6)
             group by t.numbers
             order by min(t.l)) loop
    dbms_output.put_line(r.numbers);
  end loop;

可采集：

select t.numbers bulk collect
  into t_values
  from (select regexp_substr(p_dbs, '[[:digit:]]+', 1, level) as numbers,
               level as l
          from dual
        connect by regexp_substr(p_dbs, '[[:digit:]]+', 1, level) is not null) t
 where length(t.numbers) in (5, 6)
 group by t.numbers
 order by min(t.l);

添加到原始代码

我已经通过 regexp_substr 构造对双连接进行了测试，与当前版本相比，它需要很长时间。l_sp 数字序列的开始， l_ep 数字序列的结束

我试图简化原始代码。看起来你可以不用标志。试试这个例子：

declare
  p_dbs varchar(1000) := 'MK~RU_AR~ZEN~ADFORM_CP~3301071970_CI~FY22QO_OB~1X1_TS~APV-123895_VV~NONE_PI~123895_ID~GLD0009ADF__CV~PPV-123895_FF~CPM';
  type values_t is table of varchar(150);
  t_values values_t := values_t();
  l_char   varchar2(1 char);
  l_buffer varchar2(150 char);
begin
  for i in 1 .. length(p_dbs) loop
    l_char := substr(p_dbs, i, 1);
    --Проверка на цифру
    if length(trim(translate(l_char, '01234576789', ' '))) is null then
      -- Если цифра, добавляем ее в последовательность
      l_buffer := l_buffer || l_char;
    elsif l_buffer is not null then
      --Если не цифра, то проверяем есть ли последовательность
      --Выполняем все нужные проверки
      if length(l_buffer) in (5, 6) and not l_buffer MEMBER OF t_values then
        t_values.EXTEND;
        t_values(t_values.COUNT) := l_buffer;
        dbms_output.put_line(l_buffer);
      end if;
      l_buffer := '';
    end if;
  
  end loop;
  --Проверка на случай если числовая последовательность в самом конце строки
  if l_buffer is not null then
    if (length(l_buffer) = 5 or length(l_buffer) = 6) and not l_buffer
     MEMBER OF t_values then
      t_values.EXTEND;
      t_values(t_values.COUNT) := l_buffer;
      dbms_output.put_line(l_buffer);
    end if;
    l_buffer := '';
  end if;
end;

因此，该函数可能如下所示：

create or replace function get_distinct_dbs_2(p_dbs in varchar2)
  return varchar2 deterministic as

  type values_t is table of varchar(150);
  t_values values_t := values_t();
  l_ret    varchar2(4000 char);
  l_char   varchar2(1 char);
  l_buffer varchar2(35 char);
begin
  for i in 1 .. length(p_dbs) loop
    l_char := substr(p_dbs, i, 1);
    --Проверка на цифру
    if length(trim(translate(l_char, '01234576789', ' '))) is null then
      -- Если цифра, добавляем ее в последовательность
      l_buffer := l_buffer || l_char;
    elsif l_buffer is not null then
      --Если не цифра, то проверяем есть ли последовательность
      --Выполняем все нужные проверки
      if length(l_buffer) in (5, 6) and not l_buffer MEMBER OF t_values then
        t_values.EXTEND;
        t_values(t_values.COUNT) := l_buffer;
        l_ret := l_ret || ';' || l_buffer;
      end if;
      l_buffer := '';
    end if;
  
  end loop;
  --Проверка на случай если числовая последовательность в самом конце строки
  if length(l_buffer) in (5, 6) and not l_buffer MEMBER OF t_values then
    l_ret := l_ret || ';' || l_buffer;
  end if;

  l_ret := ltrim(l_ret, ';');
  return l_ret;
end;

显然，在您的代码中，两个相互影响的条件存在错误：

--Добавили цифру, начали последовательность.
if l_test=TRUE and l_sp=false  and l_ep=false then
    l_buffer := l_buffer || l_char;
    l_sp := true;
end if;
--Если последовательность начата, то добавляем цифру еще раз
if l_test=TRUE and l_sp=true  and l_ep=false then 
    l_buffer := l_buffer || l_char;
end if;

因此，该函数会将序列的第一个字符附加两次，从而导致错误。例如，对于输入字符串1235a，将返回值11235。