主页 / 问题 / 1373746
Accepted
gregor
Asked:2022-06-21 20:09:48 +0000 UTC2022-06-21 20:09:48 +0000 UTC

发送字母时西里尔字符失真

  • 772

从 Oracle DBMS 向 Outlook 邮件发送一封包含西里尔字符的信时，输出为问号。

我不明白如何转换字符串以使文本可读。

我通过以下方式发货：

CREATE OR REPLACE PROCEDURE send_mail (p_to        IN VARCHAR2,
                                       p_from      IN VARCHAR2,
                                       p_message   IN VARCHAR2,
                                       p_smtp_host IN VARCHAR2,
                                       p_smtp_port IN NUMBER DEFAULT 25)
AS
  l_mail_conn   UTL_SMTP.connection;
BEGIN
  l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);
  UTL_SMTP.helo(l_mail_conn, p_smtp_host);
  UTL_SMTP.mail(l_mail_conn, p_from);
  UTL_SMTP.rcpt(l_mail_conn, p_to);
  UTL_SMTP.data(l_mail_conn, 'Привет мир!' || UTL_TCP.crlf || UTL_TCP.crlf);
  UTL_SMTP.quit(l_mail_conn);
END;

PS：Oracle 数据库 10g 发布 10.2.0.3.0 - 生产

oracle

1 个回答

  1. Best Answer

    通常，电子邮件的正文只能包含 7 位 US7ASCII 字符。
    因此，包含 US7ASCII 以外的字符的内容必须编码为quoted-printable或base-64，这应在电子邮件标头中指明。该文档说明了以下内容：

    使用发送的Text( VARCHAR2) 数据在发送WRITE_DATA 前转换为US7ASCII。如果文本包含多字节字符，则文本中无法转换为 US7ASCII 的每个多字节字符将替换为“？” 字符。如果使用 EHLO 子程序与 SMTP 服务器协商 8BITMIME 扩展名，则可以通过首先使用UTL_RAW包将文本转换为 RAW 来发送多字节 VARCHAR2 数据，然后使用WRITE_RAW_DATA.

    例程的最小示例如下所示：

    create or replace procedure sendMail (
        sendto varchar2, sendfrom varchar2, subj varchar2, msg varchar2, 
        host VARCHAR2, port number := 25) as
    conn utl_smtp.connection;
begin
    conn := utl_smtp.open_connection (host, port);
    utl_smtp.helo (conn, host);
    utl_smtp.mail (conn, sendfrom);
    utl_smtp.rcpt (conn, sendto);
    utl_smtp.open_data (conn);
    utl_smtp.write_data (conn, 'Subject: '||subj||UTL_TCP.crlf);
    utl_smtp.write_data (conn, 'MIME-version: 1.0'||UTL_TCP.crlf);
    utl_smtp.write_data (conn, 'Content-Type: text/plain; charset=UTF-8'    ||UTL_TCP.crlf);
    utl_smtp.write_data (conn, 'Content-Transfer-Encoding: quoted-printable'||UTL_TCP.crlf);
    utl_smtp.write_raw_data (conn, 
        utl_encode.quoted_printable_encode (utl_raw.cast_to_raw (msg)));
    utl_smtp.close_data (conn);
    utl_smtp.quit (conn);
end;
/

exec sendMail ('me', 'send-mail', 'test cyrillic', 'Привет мир!', 'localhost')

    原始结果：

    Subject: test cyrillic
MIME-version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: quoted-printable
[...]
From: send-mail@mx.local.net

=D0=9F=D1=80=D0=B8=D0=B2=D0=B5=D1=82 =D0=BC=D0=B8=D1=80!

    邮件客户端的结果：

    在此处输入图像描述

    • 3

相关问题