如何在 RAD Studio (Delphi) 的 Android 应用程序中禁用屏幕关闭？

为了我们的目的，我们使用 WAKE_LOCK

我们向清单添加权限：android.permission.WAKE_LOCK

在表单模块中，在接口部分，我们连接Androidapi.JNI.Os.pas模块：

Uses
  Androidapi.JNI.Os;

我们声明一个类变量来保存屏幕锁：

  TForm1 = class(TForm)
    ...
  private
    FWakeLock: JPowerManager_WakeLock;
    ...

在窗体显示事件中，我们调用代码来设置锁：

procedure TForm1.FormShow(Sender: TObject);
var
  PowerObj: JObject;
  PowerManager: JPowerManager;
begin
  PowerObj := TAndroidHelper.Context.getSystemService
    (TJContext.JavaClass.POWER_SERVICE);
  if Assigned(PowerObj) then
  begin
    PowerManager := TJPowerManager.Wrap((PowerObj as ILocalObject).GetObjectID);
    if Assigned(PowerManager) then
    begin
      FWakeLock := PowerManager.newWakeLock
        (TJPowerManager.JavaClass.SCREEN_DIM_WAKE_LOCK,
        StringToJString('Need to screen always on'));
      if Assigned(FWakeLock) then
      begin
        FWakeLock.acquire;
        Log('Screen WAKE_LOCK is ON');
      end;
    end;
  end;
end;

在窗体隐藏事件上，我们调用释放锁的代码：

procedure TForm1.FormHide(Sender: TObject);
begin
  if Assigned(FWakeLock) then
  begin
    FWakeLock.release;
  end;
end;

newWakeLock方法支持多个级别的 WAKE_LOCK ：

• PARTIAL_WAKE_LOCK - 确保处理器正在工作，屏幕和键盘背光可以关闭；
• FULL_WAKE_LOCK - 确保屏幕和键盘背光的全亮度（ API 级别 17 中已弃用的常量）；
• SCREEN_DIM_WAKE_LOCK - 屏幕打开，但可能是灰色的，键盘背光可能会关闭（在 API 级别 17 中常被弃用）；
• SCREEN_BRIGHT_WAKE_LOCK - 提供全屏亮度，键盘背光可以关闭（ API 级别 13 中已弃用的常量）；

WAKE_LOCK级别也可以与标志组合：

• ACQUIRE_CAUSES_WAKEUP 在 WAKE_LOCK 上调用Acquire方法时打开屏幕；
• ON_AFTER_RELEASE - 当在WAKE_LOCK上调用Release方法时，将启用用户活动计时器以使屏幕保持更长的时间。

添加到 dpr：

Application.Initialize;
{$IF DEFINED(ANDROID)}
TAndroidHelper.Activity.getWindow.addFlags(TJWindowManager_LayoutParams.JavaClass.FLAG_KEEP_SCREEN_ON); 
{$ENDIF}