主页 / 问题 / 843316
Accepted
Isaev
Asked:2020-06-18 05:11:28 +0000 UTC2020-06-18 05:11:28 +0000 UTC

在 Delphi 中重载枚举类型运算符

  • 772

是否可以为枚举类型重载运算符？那些。我们有例如：

Type
  TAngle = (a0, a90, a180, a270);

Var
  AngleA, AngleB, AngleC: TAngle;

AngleA := a90;
AngleB := a180;
AngleC := AngleA + AngleB; //a270
AngleC := a270 + AngleB;   //a90
AngleC := AngleB + a180;   //a0

理论上，加法运算符会被重载，但这仅适用于记录，据我了解？是否可以通过 Implicit 写入隐式导致这种枚举类型？但它仍然是一种新类型。

一般来说，逻辑是这样的，而我是通过一个函数来完成的：

Result := TAngle((Ord(AngleA) + Ord(AngleB)) Mod 4)
delphi

2 个回答

  1. Best Answer

    正如@zed 的回答已经说过的那样，重载仅可用于记录。因此，如果需要，您可以添加适当的结构并使用它。

    TAngleValue = (av0, av90, av180, av270);

TAngle = record
    FValue : TAngleValue;

    function getAngle():integer;
  public
    class operator Add(a, b: TAngle ):TAngle;
    class operator Implicit(angle: TAngleValue):TAngle;

    property Angle: integer read getAngle;
    property Value: TAngleValue read FValue;
end;

    重载加法，对于初学者来说，隐式转换

    class operator TAngle.Add(a, b: TAngle): TAngle;
begin
    result.FValue := TAngleValue( (byte(a.FValue) + byte(b.FValue)) mod 4);
end;

class operator TAngle.Implicit(angle: TAngleValue): TAngle;
begin
    result.FValue := angle;
end;

function TAngle.getAngle(): integer;
begin
    result := byte(FValue)*90;
end;

    最后，值的操作\u200b\u200b会变成你想要的方式

    var a, b, c : TAngle;
begin
    a := av90;
    b := av180;
    c := a + b + av90;

    writeln( a.Angle, ' ', b.Angle, ' ', c.Angle);
    readln;
end.
    • 4

  2. 你不能那样做。

    在 Delphi 的桌面版本中，运算符重载仅适用于条目：运算符重载 (Delphi)。

    对于移动版本（使用 ARC），类也可以重载：Delphi 中的类运算符

    • 2

相关问题