主页 / 问题 / 873677
Accepted
Антон
Asked:2020-08-27 01:51:29 +0000 UTC2020-08-27 01:51:29 +0000 UTC

为什么在简单的 NASM 程序中需要 _start 标签

  • 772

在网上找到一个打印“Hello, world”的NASM程序。请解释为什么_start在程序开始时需要一个标签，如果没有它一切都可以工作？（如果我没记错的话）

 global    _start

          section   .text
_start:   mov       rax, 1                  ; system call for write
          mov       rdi, 1                  ; file handle 1 is stdout
          mov       rsi, message            ; address of string to output
          mov       rdx, 13                 ; number of bytes
          syscall                           ; invoke operating system to do the write
          mov       rax, 60                 ; system call for exit
          xor       rdi, rdi                ; exit code 0
          syscall                           ; invoke operating system to exit

          section   .data
message:  db        "Hello, World", 10      ; note the newline at the end
ассемблер

1 个回答

  1. Best Answer

    让文件名test.asm，去掉全局标签_start：

    section   .text
    mov       rax, 1                  ; system call for write
    mov       rdi, 1                  ; file handle 1 is stdout
    mov       rsi, message            ; address of string to output
    mov       rdx, 13                 ; number of bytes
    syscall                           ; invoke operating system to do the write
    mov       rax, 60                 ; system call for exit
    xor       rdi, rdi                ; exit code 0
    syscall                           ; invoke operating system to exit

section   .data
message:  db        "Hello, World", 10      ; note the newline at the end

    我们收集：

    $ nasm -f elf64 test.asm
$ ld -o test test.o
ld: warning: cannot find entry symbol _start; defaulting to 00000000004000b0
$ ./test
Hello, World

    我们看到链接器正在寻找标签_start，但没有找到它，所以它选择了第一个合适的地址，即代码部分的开头.text。在反汇编器下是这样的：

    .text:00000000004000B0 ; Segment type: Pure code
.text:00000000004000B0 ; Segment permissions: Read/Execute
.text:00000000004000B0 _text           segment para public 'CODE' use64
.text:00000000004000B0                 assume cs:_text
.text:00000000004000B0                 ;org 4000B0h
.text:00000000004000B0                 assume es:nothing, ss:nothing, ds:_data, fs:nothing, gs:nothing
.text:00000000004000B0
.text:00000000004000B0 ; =============== S U B R O U T I N E =======================================
.text:00000000004000B0
.text:00000000004000B0 ; Attributes: noreturn
.text:00000000004000B0
.text:00000000004000B0                 public start
.text:00000000004000B0 start           proc near
.text:00000000004000B0                 mov     eax, 1
.text:00000000004000B5                 mov     edi, 1
.text:00000000004000BA                 mov     rsi, offset message
.text:00000000004000C4                 mov     edx, 0Dh
.text:00000000004000C9                 syscall
.text:00000000004000CB                 mov     eax, 3Ch
.text:00000000004000D0                 xor     rdi, rdi
.text:00000000004000D3                 syscall
.text:00000000004000D3 start           endp
.text:00000000004000D3
.text:00000000004000D3 _text           ends

    也就是说，原则上，程序将构建（甚至在这种情况下工作），但入口点将是链接器选择的地址。

    实际上，当需要标签时_start：

    1. 如果程序最初不应该从代码部分的开头启动（例如，某些程序先行，入口点本身在下面）
    2. 该程序可以由几个目标文件组装而成，并且在主模块代码开始之前可能还有一些其他代码（再次，这些可能是一些必要的程序，但它们不应该首先运行）

    在任何情况下，最好不要希望链接器正确地猜测到它想要什么，而是明确指定入口点。

    • 2

相关问题