主页 / 问题 / 886979
Accepted
Kir_Antipov
Asked:2020-09-29 20:37:34 +0000 UTC2020-09-29 20:37:34 +0000 UTC

使用 CIL 获取文字（常量）的值

  • 772

假设我们在编译的程序集中有一些常量。让我们举一个例子来说明Math from类mscorlib.dll和常量Math.PI

如果以-code的形式查看源码IL，那么我们会看到如下的字段声明：

.field public static literal float64 PI = float64(3.1415926535897931)

也就是说，实际上，它PI是一个标记为文字的公共静态字段
。正是因为后者，ldsfld关于Math.PI

因此，以下代码将不起作用：

.method public static float64 GetPi() cil managed
{
    .maxstack 1
    ldsfld float64 [mscorlib]System.Math::PI
    ret
}

当被调用时GetPi()，我们会得到一个运行时错误：

System.MissingFieldException：“找不到字段：'System.Math.PI'。”

在这方面，我有一个问题：是否可以通过一般手段从程序集中提取文字的值CIL，如果可以，如何做到这一点？

PS - 我非常清楚，当IL从指令创建 -code 时，例如C#常量值会立即被替换，所以：

return a * Math.PI;

将转换为：

ldloc a
ldc.r8 3.1415926535897931
mul
ret

但是，是否有一条CIL指令仍然可以提取常量字段的值仍然很有趣

.net

2 个回答

  1. Best Answer

    CIL规范非常明确地指出：

    I.8.6.1.2 位置签名

    文字约束承诺位置的值实际上是内置类型的固定值。该值被指定为约束的一部分。编译器需要用它的值替换对位置的所有引用，因此 VES 不需要为该位置分配空间。此约束虽然在逻辑上适用于任何位置，但只能放置在复合类型的静态字段上。不允许从 CIL 引用如此标记的字段（它们应在编译时内联到它们的常量值），但可以使用反射和直接处理元数据的工具获得。

    精选作品

    如此标记的字段不允许从 CIL 中引用

    以这种方式标记的字段不能从 CIL 访问

    所以不，CIL 中没有这样的指令。

    但是，如同一段所述：

    但可以使用直接处理元数据的反射和工具来使用。

    但在使用反射或直接处理元数据的工具时可用。

    翻译CIL 问题的答案 - 如何使用公共静态文字字段？

    • 5

  2. 添加到@Grundy的答案 ：

    如前所述，不可能CIL通过常规方式获取文字的值，因此您应该使用反射

    实际上，这就是我们要做的）
    结果是这样的generic方法：

    .method public static !!ConstType GetConst<ConstType>(class [mscorlib]System.Type, string) cil managed 
{
    .maxstack 3
    ldarg.0     // Кладем на стек тип, из которого будем тащить константу
    ldarg.1     // Кладем на стек название литерала
    ldc.i4 56   // Кладем на стек значение BindingFlags.Static | BindingFlags.Public | BindingFlags.NonPublic
                // т.к. константа всегда является полем статичным и не совсем обязательно публичным)

    // Достанем FieldInfo
    callvirt instance class [mscorlib]System.Reflection.FieldInfo [mscorlib]System.Type::GetField(string, valuetype [mscorlib]System.Reflection.BindingFlags)
    ldnull

    // Получим его значение
    callvirt instance object [mscorlib]System.Reflection.FieldInfo::GetValue(object)

    // Распакуем
    unbox.any !!ConstType

    // Вернем
    ret
}

    然后方法GetPi()可以改写成这样：

    .method public static float64 GetPi() cil managed
{
    .maxstack 2
    // Получим тип класса System.Math
    ldtoken [mscorlib]System.Math
    call class [mscorlib]System.Type [mscorlib]System.Type::GetTypeFromHandle(valuetype [mscorlib]System.RuntimeTypeHandle)

    // Укажем, какую константу хотим из него вытащить
    ldstr "PI"

    // И, собственно, вытащим)
    call !!0 ILConsole.Program::GetConst<float64>(class [mscorlib]System.Type, string)
    ret
}

    现在方法调用不会落入runtime，而是会返回预期值System.Math.PI）

    我再次强调，常量就是常量，它们的不可变值会立即替换到IL-code 中，因此在编写某种编译器时，您不应该使用上面的代码，而应该简单地手动将所需的值写入其中应该

    此答案仅用于教育目的）

    • 2

相关问题